/// @ 0.11.1
### {
  name: "Highlighter"
  version: "0.11.1.0.001"
  author: "@box464@calckey.social"
  description: "Highlight a word or short phrase found in a note on your timelines. View settings to change the phrase, set colors, and enable or disable the sparkle effect."
  permissions: []
  config: {
    searchTerm: {
      type: "string"
      label: "Search Phrase"
      description: "Required. A word or short phrase that will be highlighted and sparkled on your timelines when found."
      default: ""
    }
    enableCompatibilityMode: {
      type: "boolean"
      label: "Compatibility Mode"
      description: "Enabled by default. Firefish instances running version v13.1.4.1 or lower do not have MFM foreground and background properties, which causes a display issue."
      default: yes
    }
    bgColor: {
      type: "string"
      label: "Background Color"
      description: "The HEX code you want to use for the background color of the search phrase. Requires Firefish version v13.2.0.0 beta or higher."
      default: "D8D7B0"
    }
    fgColor: {
      type: "string"
      label: "Text Color"
      description: "Required. The HEX code you want to use for the text color of the search phrase. Requires Firefish version v13.2.0.0 beta or higher."
      default: "31748F"
    }
    enableSparkle: {
      type: "boolean"
      label: "Sparkle Effect"
      description: "Enable sparkle effect on search phrases."
      default: yes
    }
    debug: {
      type: "boolean"
      label: "Enable Debugging"
      description: "Write debugging information to the console."
      default: no
    }
  }
}

@debug(comment) {
  ? (Plugin:config.debug = yes) {
    $_comment <- comment
    _comment <- Arr:join(["Plugin: Highlighter: " _comment])
    print(comment)
  }
}

#c = {}
c.searchTerm <- Plugin:config.searchTerm
c.bgColor <- Plugin:config.bgColor
c.fgColor <- Plugin:config.fgColor
c.enableSparkle <- Plugin:config.enableSparkle
c.enableCompatibilityMode <- Plugin:config.enableCompatibilityMode

? (c.bgColor = "") {
  c.bgColor <- "D8D7B0"
}

? (c.fgColor = "") {
  c.fgColor <- "31748F"
}

c.bgColor <- Str:replace(c.bgColor, "#", "")
c.fgColor <- Str:replace(c.fgColor, "#", "")

// The term effect is just a code pattern I use. It's not required.
// I break my code into handler and effect functions to make it easier to read and debug.
@effect(note) {
  ? (c.searchTerm != "") {
    debug("Search Term Exists 🕵🏾‍♀️")

    $noteText <- ""

    ? Core:eq(note.text, _) {
      noteText <- ""
    } . {
      noteText <- note.text
    }

    $wordReplacement <- ""

    #noteUpper = Str:upper(noteText)

    ? (Str:index_of(noteUpper, Str:upper(c.searchTerm)) > 0) {

      debug("Search Term Found")
      ? (c.enableSparkle = yes) {
        debug("✨ Starting Sparkles")
        wordReplacement <- " $[sparkle "
      }

      ? (c.enableCompatibilityMode = yes) {
        debug("Using Code instead of Colors")
        wordReplacement <- Arr:join([wordReplacement "$[x2  ` " c.searchTerm " ` ]"])
      } . {
        debug("Applying Colors")
        wordReplacement <- Arr:join([wordReplacement "$[x2 $[bg.color=" c.bgColor " $[fg.color=" c.fgColor "  " c.searchTerm " ]]]"])
      }

      ? (c.enableSparkle = yes) {
        debug("✨ Finishing Sparkles")
        wordReplacement <- Arr:join([wordReplacement "]"])
      }

      debug("📚 Defining Search Term Derivatives")
      #wordReplacementHash = Str:replace(wordReplacement, c.searchTerm, Arr:join(["#" c.searchTerm]))
      #searchTerm = Str:lower(c.searchTerm)
      #searchTermLower = Str:lower(c.searchTerm)
      #searchTermUpper = Str:upper(c.searchTerm)
      #searchTermFirstUpper = Arr:join([Str:upper(Str:slice(c.searchTerm, 1, 2)) Str:lower(Str:slice(c.searchTerm, 2, (Str:len(c.searchTerm) + 1)))])
      #searchTermHashUpper = Arr:join(["#" Str:upper(c.searchTerm)])

      debug("🔖 Highlighting Search Term")

      noteText <- Str:replace(noteText, c.searchTerm, searchTermUpper)
      noteText <- Str:replace(noteText, searchTermLower, searchTermUpper)
      noteText <- Str:replace(noteText, searchTermFirstUpper, searchTermUpper)
      noteText <- Str:replace(noteText, Arr:join([":" searchTermUpper ":"]), searchTermLower)

      noteText <- Str:replace(noteText, searchTermHashUpper, wordReplacementHash)
      noteText <- Str:replace(noteText, Arr:join([" " searchTermUpper]), wordReplacement)
      noteText <- Str:replace(noteText, searchTermUpper, wordReplacement)

      debug("🎉 Returning updated note text")
      debug(noteText)
      note.text <- noteText
    }
  }

  note
}

// The term handler is just my own code pattern. You can use whatever you want.
@handler(note_) {
  debug("Begin Handler")

  // Apply this effect not only to the main note, but any replies or renotes as well.
  $note <- effect(note_)
  ? Obj:has(note, "renote") { note.renote <- effect(note.renote) }
  ? Obj:has(note, "reply") { note.reply <- effect(note.reply) }

  debug("End Handler")

  note
}

Plugin:register_note_view_interruptor(handler)